Funciones Matematicas

CONVERTIR

Convierte un valor de una unidad de medida a otra. Los factores de conversión se proporcionan en una lista en la configuración.
En su momento, la lista de factores de conversión incluía las monedas europeas heredadas y el euro (ver los ejemplos a continuación). Se recomienda utilizar la nueva función EUROCONVERT para convertir estas monedas.

Sintaxis

CONVERTIR(valor;"texto";"texto")

Ejemplo

=CONVERTIR(100;"ATS";"EUR") devuelve el valor en euros de 100 chelines austríacos.
=CONVERTIR(100;"EUR";"DEM") convierte 100 euros en marcos alemanes.

MÚLTIPLO.INFERIOR

Redondea un número hacia abajo hasta el múltiplo de cifra_significativa más próximo.

Sintaxis

MÚLTIPLO.INFERIOR(número; cifra_significativa; modo)
Número es la cifra que se debe redondear hacia abajo.
cifra_significativa es el número cuyo valor de múltiplo se debe redondear hacia abajo.
Modo es un valor opcional. Si se proporciona el valor Modo y no es igual a cero, y si su Número y cifra significativa son negativos, el redondeo se efectúa según el valor absoluto del número. Este parámetro se omite al exportarse a MS Excel, ya que dicho programa no conoce ningún tercer parámetro.

Si ambos parámetros Número y Cifra significatica son negativos, y si el valor Modo es igual a cero o no esta especificado, los resultados en LibreOffice Calc y Excel serán diferentes luego de exportar. Si exporta la hoja de cálculo a Excel, use Modo=1 para ver los mismos resultados en Excel como en Calc.

Ejemplo

=MÚLTIPLO.INFERIOR( -11;-2) devuelve -12.
=MÚLTIPLO.INFERIOR( -11;-2;0) devuelve -12.
=MÚLTIPLO.INFERIOR( -11;-2;1) devuelve -10.

SIGNO

Devuelve el signo de un número. La función devuelve como resultado 1 si el signo es positivo y -1 si es negativo. Si el número es cero, la función devuelve también un cero.

Sintaxis

SIGNO(Número)
Número es el número cuyo signo debe determinarse.

Ejemplo

=SIGNO(3.4) devuelve 1.
=SIGNO(-4.5) devuelve -1.

REDOND.MULT

El resultado es el múltiplo entero más próximo del número.

Sintaxis

REDOND.MULT(Número; Múltiplo)
Devuelve Número redondeado al multiplo mas cercano a Múltiplo.
Una implementación alternativa será Múltiplo * REDOND(Número/Multiplo).

Ejemplo

=REDOND.MULT(15,5;3) devuelve 15, ya que 15,5 está más cercano a 15 (= 3*5) que a 18 (= 3*6).
=REDOND.MULT(1.4;0.5) da como resultado 1,5 (= 0,5*3).

CONTAR.BLANCO

Devuelve el número de celdas vacías. Escriba las referencias de las celdas separadas por dos puntos en el campo de texto de área.

Sintaxis

CONTAR.BLANCO(Rango)
Devuelve el número de celdas vacías en el rango de celdasRango.

Ejemplo

=CONTAR.BLANCO(A1:B2) devuelve 4 si las celdas A1, A2, B1 y B2 están vacías.

ACOS

Devuelve la inversa del coseno trigonométrico de un número.

Sintaxis

ACOS(Número)
_Esta función devuelve la inversa del coseno trigonométrico del Número, que es el ángulo (en radianes) cuyo coseno es Número. El ángulo devuelto esta entre 0 y PI.
Para volver el ángulo en grados, use la función GRADOS.

Ejemplo

=ACOS(-1) devuelve 3,14159265358979 (PI radianes).
=GRADOS(ACOS(0,5)) devuelve 60. El coseno de 60 grados es 0,5.

ACOSH

Devuelve el inverso del coseno hiperbólico de un número.

Sintaxis

ACOSH(Número)
Esta función devuelve el inverso del coseno hiperbólico de Número, que es el número cuyo coseno hiperbólico es Número.
Número debe ser mas o igual que 1.

Ejemplo

=ACOSH(1) devuelve 0.
=ACOSH(COSH(4)) devuelve 4.

RAÍZ

Devuelve la raíz cuadrada positiva de un número. El número debe ser positivo.

Sintaxis

RAÍZ(Número)
Devuelve la raíz cuadrada positiva de Número.
El número debe ser positivo.

Ejemplo

=RAÍZ(16) devuelve 4.
=RAIZ(-16) devuelve un error de argumento no válido.

ACOT

Devuelve el inverso de la cotangente del número especificado.

Sintaxis

ACOT(Número)
Esta función devuelv()e la cotangente trigonométrica inversa del Número, que es el ángulo (en radianes) cuyo número es cotangente. El ángulo que devuelve está entre 0 y PI.
Para volver el ángulo en grados, use la función GRADOS.

Ejemplo

=ACOT(1) devuelve 0,785398163397448 (PI/4 radianes).
=GRADOS(ACOT(1)) devuelve 45. La tangente de 45 grados es 1.

ACOTH

Devuelve el inverso de la cotangente hiperbólica del número especificado.

Sintaxis

ACOTH(Número)
Esta función devuelve la inversa de la cotangente hiperbólica de Número, que es el número cuya cotangente hiperbólica es Número.
Un resultado da error si Número esta entre -1 y 1, ambos inclusive.

Ejemplo

=ACOTH(1.1) devuelve la cotangente hiperbólica inversa de 1,1, aproximadamente 1,52226.

ASENO

Devuelve la inversa del seno trigonométrico de un número.

Sintaxis

ASENO(Número)
Esta función devuelve el seno trigonométrico inverso del Número, que es el ángulo (en radianes) cuyo seno es el Número. El ángulo que se muestra está entre -PI/2 y +PI/2.
To return the angle in degrees, use the DEGREES function.

Ejemplo

=ASENO(0) devuelve 0.
=ASENO(1) devuelve 1,5707963267949 (PI/2 radianes).
=GRADOS(ASENO(0,5)) devuelve 30. El seno de 30 grados es 0,5.

ASENOH

Devuelve el seno hiperbólico inverso de un número.

Sintaxis

ASENOH(Número)
Esta función devuelve el seno hiperbólico inverso del Número, que es el número cuyo seno hiperbólico es el número.

Ejemplo

=ASENOH(-90) da como resultado aproximadamente -5,1929877.
=ASENOH(SENOH(4)) devuelve 4.

ATAN

Devuelve la inversa de la tangente trigonométrica de un número.

Sintaxis

ATAN(Número)
Esta función devuelve la tangente trigonométrica inversa del Número, que es el ángulo (en radianes) cuya tangente es el número. El ángulo muestra está entre -PI/2 y PI/2.
To return the angle in degrees, use the DEGREES function.

Ejemplo

=ATAN(1) devuelve 0,785398163397448 (PI/4 radianes).
=GRADOS(ATAN(1)) devuelve 45. La tangente de 45 grados es 1.

ATAN2

Devuelve la inversa de la tangente trigonométrica de las coordenadas x e y especificadas.

Sintaxis

ATAN2(NúmeroX; NúmeroY)
NúmeroX es el valor de la coordenada x.
NúmeroY es el valor de la coordenada y.
ATAN2 devuelve la tangente trigonométrica inversa, que es, el ángulo (en radianes) entre el eje X y una línea desde el punto NúmeroX, NúmeroY al origen.El ángulo que muestra está entre -PI y PI.
To return the angle in degrees, use the DEGREES function.

Ejemplo

=ATAN2(20;20) devuelve 0,785398163397448 (PI/4 radianes).
=GRADOS(ATAN2(12,3;12,3)) devuelve 45. La tangente de 45 grados es 1.

ATANH

Devuelve la tangente hiperbólica inversa de un número.

Sintaxis

ATANH(Número)
Esta función devuelve la inversa de la tangente hiperbólica del Número, que es el número cuya tangente hiperbólica es Número.
El número debe obedecer a la condición -1 < número < 1.

Ejemplo

=ATANH(0) devuelve 0.

COS

Devuelve el coseno del número (ángulo) especificado.

Sintaxis

COS(Número)
Número es el valor cuyo coseno debe calcularse.
To return the cosine of an angle in degrees, use the RADIANS function.

Ejemplos

=COSENO(PI()/2) devuelve 0, el coseno de PI/2 radianes.
=COSENO(RADIANES(60)) devuelve 0,5, el coseno de 60 grados.

COSH

Devuelve el coseno hiperbólico de un número.

Sintaxis

COSH(Número)
Número es el valor cuyo coseno hiperbólico debe calcularse.

Ejemplo

=COSH(0) devuelve 1, el coseno hiperbólico de 0.

COT

Devuelve la cotangente del ángulo especificado.

Sintaxis

COT(Número)
Número es el valor cuya cotangente debe calcularse.
Para regresar la cotangente de un angulo en grados, usa la función de RADIANES.
The cotangent of an angle is equivalent to 1 divided by the tangent of that angle.

Ejemplo:

=COT(PI()/4) devuelve 1, la cotangente de PI/4 radianes.
=COT(RADIANES(45)) devuelve 1, la cotangente de 45 grados.

RAIZ2PI

Devuelve la raíz cuadrada de un número multiplicado por pi.

Sintaxis

RAIZ2PI(Número)
Devuelve la raíz cuadrada positiva de (PI multiplicado por el Número).
Esto es equivalente aRAÍZ(PI()*Número).

Ejemplo

=RAIZ2PI(2) devuelve la raíz cuadrada de (2PI), aproximadamente 2,506628.

COTH

Devuelve la cotangente hiperbólica de un número (ángulo) especificado.

Sintaxis

COTH(Número)
Número es el valor cuyo cotangente hiperbólica debe calcularse.

Ejemplo

=COTH(1) devuelve la cotangente hiperbólica de 1, aproximadamente 1,3130.

GRADOS

Convierte radianes en grados.

Sintaxis

GRADOS(numero)
Número es el ángulo en radianes que se convertirá a grados.

Ejemplo

=GRADOS(PI()) da como resultado 180 grados.

EXP

Devuelve el resultado de elevar un número a una potencia. La constante e tiene un valor aproximado de 2,71828182845904.

Sintaxis

EXP(Número)
Número es la potencia a la que se elevará el número e.

Ejemplo

=EXP(1) devuelve 2,71828182845904, la constante matemática e con la precisión de Calc.

FACT

Devuelve el factorial de un número. FACT(0) devuelve 1. FACT(n) devuelve 1*2*3*4* ... *n.

Sintaxis

FACT(Número)
Devuelve Número!, el factorial de Número, calculado como 1*2*3*4* ... * Número.
=FACT(0) devuelve 1 por definición.
El valor de un número negativo devuelve el error "argumento inválido".

Ejemplo

=FACT(3) devuelve 6.
=FACT(0) devuelve 1.

ENTERO

Redondea un número hacia abajo hasta el entero más próximo.

Sintaxis

ENTERO(Número)
Devuelve el Número redondeado al entero mas cercano.
Los números negativos se redondean al entero inferior.

Ejemplo

=ENTERO(5.7) devuelve 5.
=ENTERO(-1,3) devuelve -2.

REDONDEA.PAR

Redondea un número positivo hacia arriba hasta el entero par más próximo y un número negativo hacia abajo hasta el entero par más próximo.

Sintaxis

REDONDEA.PAR(Número)
Devuelve Número redondeado al siguiente entero par, lejos de cero.

Ejemplos

=REDONDEA.PAR(2.3) devuelve 4.
=REDONDEA.PAR(2) devuelve 2.
=REDONDEA.PAR(0) devuelve 0.
=REDONDEA.PAR(-0.5) devuelve -2.

M.C.D

Devuelve el máximo común divisor de dos o más enteros.
El máximo común divisor es el entero positivo más grande que divide, sin resto, cada uno de los enteros dados.

Sintaxis

GCD(Entero1; Entero2; ...; Entero30)
Enteros de 1 a 30 son hasta 30 números enteros de los que debe calcularse el máximo común divisor.

Ejemplo

=M.C.D(16;32;24) da 8 como resultado, porque 8 es el mayor número que puede dividir 16, 24 y 32 sin resto.
=M.C.D.(B1:B3) donde las celdas B1, B2, B3 contienen 9, 12, 9 da como resultado 3.

M.C.D_ADD

El resultado es el máximo común divisor de una lista de números.

Las funciones cuyo nombre termina con _ADD devuelven el mismo resultado que las funciones correspondientes de Microsoft Excel. Utilice las funciones sin _ADD para obtener resultados basados en estándares internacionales. Por ejemplo, la función SEM.DEL.AÑO calcula el número de semana de una fecha concreta basándose en el estándar internacional ISO 6801, mientras que SEM.DEL.AÑO_ADD devuelve el mismo número de semana que Microsoft Excel.

Sintaxis

GGT_ADD(Número(s))
Número(s) es una lista de hasta 30 números.

Ejemplo

=MCD_ADD(5;15;25) devuelve 5.

ESPAR

Devuelve VERDADERO si el valor es un entero par, y FALSO si es impar.

Sintaxis

ESPAR(Valor)
Valor es el valor que se debe verificar.
Si el valor no es un entero cualquier dígito después del punto decimal se ignora. El signo de valor también es ignorado.

Ejemplo

=ESPAR(48) devuelve VERDADERO.
=ESPAR(33) devuelve FALSO.
=ESPAR(0) devuelve VERDADERO.
=ESPAR(-2.1) devuelve VERDADERO.
=ESPAR(3,999) devuelve FALSO.

ESIMPAR

Devuelve VERDADERO si el valor es impar, y FALSO si es par.

Sintaxis

ESIMPAR(Valor)
Valor es el valor que se debe verificar.
Si el valor no es un entero cualquier dígito después del punto decimal se ignora. El signo de valor también es ignorado.

Ejemplo

=ESIMPAR(33) devuelve VERDADERO.
=ESIMPAR(48) devuelve FALSO.
=ESIMPAR(3.999) devuelve VERDADERO.
=ESIMPAR(-3.1) devuelve VERDADERO.

ALEATORIO.ENTRE

Devuelve un número entero aleatorio entre menor y mayor (ambos incluidos). Para recalcular, pulse Mayús + Control + F9.

Sintaxis

ALEATORIO.ENTRE (menor; mayor)
Devuelve un entero de números aleatorios entre enterosInferior y Superior (ambos inclusive).
Esta función genera un nuevo número aleatorio cada vez que Calc vuelve a calcular. Para forzar a Calc a que vuelva a calcular manualmente, pulse Mayús+Ctrl+F9.
Para generar números aleatorios que nunca recalcular, copie el contenido de las celdas de esta funció, y use Editar - Pegado especial (with Pegar todo y Fórmulas no marcadas y Números marcados).

Ejemplo

=ALEATORIO.ENTRE(20;30) devuelve un entero entre 20 y 30.

M.C.M

Devuelve el mínimo común múltiplo de uno o más enteros.

Sintaxis

M.C.M(Entero1; Entero2; ...; Entero30)
Enteros de 1 a 30 son números hasta 30 números enteros de los que debe calcularse el mínimo común múltiplo.

Ejemplo

Si ingresa los números 512;1024 y 2000 en el cuadro de texto 1;2 y 3, 128000 se devolverá como resultado.

MCM_ADD

El resultado es el mínimo común múltiplo de una lista de números.

Las funciones cuyo nombre termina con _ADD devuelven el mismo resultado que las funciones correspondientes de Microsoft Excel. Utilice las funciones sin _ADD para obtener resultados basados en estándares internacionales. Por ejemplo, la función SEM.DEL.AÑO calcula el número de semana de una fecha concreta basándose en el estándar internacional ISO 6801, mientras que SEM.DEL.AÑO_ADD devuelve el mismo número de semana que Microsoft Excel.

Sintaxis

MCM_ADD(Número(s))
Número(s) es una lista de hasta 30 números.

Ejemplo

=MCM_ADD(5;15;25) devuelve 75.

COMBINAR

Devuelve el número de combinaciones para un número determinado de objetos sin repeticiones.

Sintaxis

COMBINAR(Contar1; Contar2)
Contar1 es el número de elementos en el conjunto.
Contar2 es el número de elementos que elegir en el conjunto.
COMBINAR devuelve el número de maneras de elegir esos elementos. Por ejemplo si hay 3 elementos A, B y C en un conjunto, puede elegir 2 elementos de 3 diferentes maneras: AB, AC y BC.
COMBINAR aplica la siguiente fórmula: Contar1!/(Contar2!*(Contar1-Contar2)!)

Ejemplo

=COMBINAR(3;2) devuelve 3.

COMBINAR2

Devuelve el número de combinaciones para un número determinado de objetos incluyendo las repeticiones.

Sintaxis

COMBINAR(Contar1; Contar2)
Contar1 es el número de elementos en el conjunto.
Contar2 es el número de elementos que elegir en el conjunto.
COMBINATA devuelve la cantidad de maneras únicas de elegir esos elementos, donde el orden de elección es irrelevante. Por ejemplo, si hay 3 elementos A, B y C en un conjunto, pueden elegir 2 elementos de 6 maneras diferentes: AA, AB, AC, BB, BC y CC.
COMBINAR aplica la siguiente fórmula: (Contar1+Contar2-1)!/(Contar2!(Contar1-1)!)

Ejemplo

=COMBINA(3;2) devuelve 6.

TRUNCAR

Trunca un número al eliminar lugares decimales de la cifra según la precisión que se haya indicado en Cantidad.

Sintaxis

TRUNCAR(Número; Cuenta)
Devuelve el Número al menos Contar espacios decimales. El exceso de decimales son eliminados, independientemente de su signo.
TRUNCAR(Número; 0) se comporta como ENTERO(Número) para los números positivos, pero en la práctica redondea hacia cero para los números negativos.

La cantidad de decimales visibles del resultado se especifican en Herramientas - Opciones - LibreOffice Calc - Calcular.

Ejemplo

=TRUNCAR(1,239;2) devuelve 1,23. El 9 se pierde.
=TRUNCAR(-1.234999;3) devuelve -1.234. Se pierden todos los 9.

LN

Devuelve el logaritmo natural basándose en la constante e de un número. La constante e tiene un valor aproximado de 2.71828182845904.

Sintaxis

LN(Número)
Número es el valor cuyo logaritmo natural debe calcularse.

Ejemplo

=LN(3) devuelve el logaritmo natural de 3 (aproximadamente 1,0986).
=LN(EXP(321)) devuelve 321.

LOG

Devuelve el logaritmo de un número en la base especificada.

Sintaxis

LOG(Número; Base)
Número es el valor cuyo logaritmo debe calcularse.
Base (opcional) es la base empleada para el cálculo del logaritmo. Si se omite, se asume la base 10.

Ejemplo

=LOG(10;3) devuelve el logaritmo con base 3 de 10 (aproximadamente 2,0959).
=LOG(7^4;7) devuelve 4.

LOG10

Devuelve el logaritmo en base 10 de un número.

Sintaxis

LOG10(Número)
Devuelve el logaritmo en base 10 de un Número.

Ejemplo

=LOG10(5) devuelve el logaritmo en base 10 de 5 (aproximadamente 0,69897).

MÚLTIPLO.SUPERIOR

Redondea un número hacia arriba hasta el múltiplo de cifra_significativa más próxima.

Sintaxis

MÚLTIPLO.SUPERIOR(Número; Cifra significativa; Modo)
Número es la cifra que se debe redondear.
cifra_significativa es el número cuyo valor de múltiplo se debe redondear hacia arriba.
Modo es un valor opcional. Si se proporciona el valor Modo y no es igual a cero, y su Número y cifra significativa son negativos, el redondeo se efectúa según el valor absoluto del número. Este parámetro se omite al exportarse a MS Excel, ya que dicho programa no conoce ningún tercer parámetro.

Si ambos parámetros Número y Cifra significativa son negativos y el valor Modo es igual a cero o no es dado, el resultado en LibreOffice y Excel será diferente luego que la importación se haya completado. Si exporta la hoja de cálculo para Excel, use Modo=1 para ver el mismo resultado en Excel como en Calc.

Ejemplo

=MÚLTIPLO.SUPERIOR(-11;-2) devuelve -10.
=MÚLTIPLO.SUPERIOR(-11;-2;0) devuelve -10.
=MÚLTIPLO.SUPERIOR(-11;-2;1) devuelve -12.

PI

Devuelve 3,14159265358979, el valor de la constante matemática PI en 14 decimales.

Sintaxis

PI()

Ejemplo

=PI() devuelve 3,14159265358979.

ALEATORIO

Devuelve un número aleatorio entre 0 y 1.

Sintaxis

ALEATORIO( )
Esta función genera un nuevo número aleatorio cada vez que Calc vuelve a calcular. Para forzar a Calc a que vuelva a calcular manualmente, pulse Mayús+Ctrl+F9.
Para generar números aleatorios que nunca recalcular, copie el contenido de cada celda =ALEATORIO(), y use Editar - Pegado especial (with Pegar todo y Fórmulas no marcadas y Números marcados).

Ejemplo

=ALEATORIO() da como resultado un número aleatorio entre 0 y 1.

MULTINOMIAL

Devuelve el factorial de la suma de los argumentos dividido por el producto de los factoriales de los argumentos.

Sintaxis

MULTINOMIAL(Número(s))
Número(s) es una lista de hasta 30 números.

Ejemplo

=MULTINOMIAL(F11:H11) devuelve 1260, si F11 a H11 contiene los valores 2, 3 y 4. Esto se corresponde a la fórmula =(2+3+4) / (2!*3!*4!)

POTENCIA

Devuelve el resultado de elevar un número a una potencia.

Sintaxis

POTENCIA(Base; Exponente)
Devuelve la Base elevada a la potencia del Exponente.
The same result may be achieved by using the exponentiation operator ^:
<code>Base^Exponente</code>

Ejemplo

=POTENCIA(4;3) devuelve 64, que es 4 a la 3.ª potencia.
=4^3 también devuelve 4 para la potencia de 3.

SUMA SERIES

Suma el primer termino de una serie de potencias.
SUMA SERIES(x;n;m;coeficientes) = coeficiente_1*x^n + coeficiente_2*x^(n+m) + coeficiente_3*x^(n+2m) +...+ coeficiente_i*x^(n+(i-1)m)

Sintaxis

SUMA.SERIES(X; N; M; Coeficientes)
X es el valor de entrada para la serie de potencias.
N es la primera potencia.
M es el incremento para aumentar N.
Coeficientes es una serie de coeficientes. Para cada coeficiente, la suma de la serie se amplía en una sección.

PRODUCTO

Multiplica todos los números indicados como argumentos y devuelve el producto.

Sintaxis

PRODUCTO(Número1; Número2; ...; Número30)
Número1 a 30 son hasta 30 argumentos cuyo producto se va a calcular.
PRODUCTO devuelve número1 * número2 * número3 * ...

Ejemplo

=PRODUCTO(2;3;4) devuelve 24.

SUMA.CUADRADOS

Para obtener la suma de cuadrados de varios números (suma de los cuadrados de los argumentos), introduzca lo siguiente en los campos de texto.

Sintaxis

SUMA.CUADRADOS(Número1; Número2; ...; Número30)
Número1 a 30 son hasta 30 argumentos cuya suma de los cuadrados se va a calcular.

Ejemplo

Si ingresa los números 2; 3 y 4 en el cuadro de texto 1; 2 y 3, 29 se devolverá como resulado.

RESIDUO

Permite calcular el residuo de una división por un número.

Sintaxis

RESIDUO(Dividendo; Divisor)
Los argumentos enteros para esta función devuelven Dividendo por Divisor, que es cuando el remanente Dividendo se divide por Divisor.
Esta función es implementada como Dividendo - Divisor * ENTERO(Dividendo/Divisor) , y esta fórmula da los resultados si el argumento no es un entero.

Ejemplo

=RESIDUO(22;3) devuelve 1, el resto cuando 22 se divide por 3.
=RESIDUO(11,25;2,5) devuelve 1,25

COCIENTE

Devuelve la parte entera de una división.

Sintaxis

COCIENTE(Numerador; Denominador)
Devuelve la parte entera del Numerador dividido por el Denominador.
COCIENTE es equivalente a ENTERO(numerador/denominador), excepto que pueda reportar errores con diferentes códigos de error.

Ejemplo

=COCIENTE(11;3) devuelve 3. El resto de 2 se pierde.

RADIANES

Convierte grados en radianes.

Sintaxis

RADIANES(Número)
Número es el ángulo en grados que se convertirá a radianes.

Ejemplo

=RADIANES(90) da como resultado 1,5707963267949, que es PI/2 en la precisión de Calc.

REDONDEAR

Devuelve un número redondeado hasta una cantidad determinada de decimales.

Sintaxis

REDONDEAR(Número; Contar)
Devuelve el Número redondeado a Contar posiciones decimales. Si Contar se omite o es cero, la función redondea al entero más cercano. Si Contar es negativo, la función redondea a 10, 100, 1000, etc., más cercano.
This function rounds to the nearest number. See ROUNDDOWN and ROUNDUP for alternatives.

Ejemplo

=REDONDEAR(2,348;2) devuelve 2,35.
=REDONDEAR(-32.4834;3) devuelve -32.483. Cambie el formato de la celda para ver todos los decimales.
=REDONDEAR(2,348;0) devuelve 2.
=REDONDEAR(2,5) devuelve 3.
=REDONDEAR(987,65;-2) devuelve 1.000.

REDONDEAR.MENOS

Redondea un número hacia abajo, hacia cero.

Sintaxis

REDONDEAR.MENOS(Número; Contar)
Devuelve el Número redondeado hacia abajo (hacia cero) para Contarespacios decimales. Si Contar es omitido o es cero, la función redondea al entero más cercano hacia abajo. Si Contar es negativo, la función redondea hacia abajo al más cercano 10, 100, 1000, etc.
This function rounds towards zero. See ROUNDUP and ROUND for alternatives.

Ejemplo

=REDONDEAR.MENOS(1,234;2) devuelve 1,23.
=REDONDEAR.MENOS(45.67;0) devuelve 45.
=REDONDEAR.MENOS(-45,67) devuelve -45.
=REDONDEAR.MENOS(987.65;-2) devuelve 900.

CONTAR.SI

Devuelve el número de celdas que cumplen determinados criterios.
La búsqueda admite expresiones regulares. Puede escribir "todo.*", por ejemplo, para buscar la primera aparición de "todo" seguido por cualquier combinación de caracteres. Si desea buscar un texto que sea a su vez una expresión regular, cada carácter debe ir precedido con el carácter \ (barra invertida). Puede activar y desactivar la evaluación automática de expresiones regulares en Herramientas - Opciones - LibreOffice Calc - Calcular.

Sintaxis

CONTAR.SI(Rango; Criterio)
Rango es el área en la que se aplicarán los criterios.
Criterios indica los criterios en forma de número, expresión o cadena de caracteres. Estos criterios determinan las celdas que se cuentan. Un criterio de búsqueda puede formularse como una expresión regular, por ejemplo "b.*" para todas las palabras que empiecen por "b". También es posible indicar un rango de celdas que contenga un criterio de búsqueda. Si busca texto literal, delimite el texto con comillas dobles.

Ejemplo

A1:A10 es un rango de celda que contienen los números 2000 a 2009. Celda B1 contiene el número 2006. En la celda B2, ingresa una fórmula:
=CONTAR.SI(A1:A10;2006) da como resultado 1.
=CONTAR.SI(A1:A10;B1) da como resultado 1.
=CONTAR.SI(A1:A10;">=2006") da como resultado 4.
=CONTAR.SI(A1:A10;"<"&B1); cuando B1 contiene 2006, devuelve 6.
=CONTAR.SI(A1:A10;C2) donde la celda C2 contiene el texto >2006 cuenta el número de celdas en el área A1:A10, que son >2006.
Para contar únicamente números negativos: =CONTAR.SI(A1:A10;"<0")

REDONDEAR.MAS

Devuelve un número redondeado hacia arriba hasta el número especificado de decimales.

Sintaxis

REDONDEAR.MAS(Número; Contar)
Devuelve el Número redondeado hacia arriba (lejos desde el cero) para Contar espacios decimales. Si Contar es omitido o es cero, la función redondea hacia arriba a un entero. Si Contar es negativo, la función redondea hacia arriba, al siguiente 10, 100, 1000, etc.
This function rounds away from zero. See ROUNDDOWN and ROUND for alternatives.

Ejemplo

=REDONDEAR.MAS(1.1111;2) devuelve 1.12.
=REDONDEAR.MAS(1,2345;1) devuelve 1,3.
=REDONDEAR.MAS(45,67;0) devuelve 46.
=REDONDEAR.MAS(-45.67) devuelve -46.
=REDONDEAR.MAS(987.65;-2) devuelve 1.000.

SENO

Devuelve el seno del número (ángulo) especificado.

Sintaxis

SENO(Número)
Devuelve el seno (trigonométrico) del Número, el ángulo en radianes.
To return the sine of an angle in degrees, use the RADIANS function.

Ejemplo

=SENO(PI()/2) devuelve 1, el seno de PI/2 radianes.
=SENO(RADIANES(30)) da como resultado 0,5, el seno de 30 grados.

SENOH

Devuelve el seno hiperbólico de un número.

Sintaxis

SENOH(Número)
Devuelve el seno hiperbólico del Número.

Ejemplo

=SENOH(0) devuelve 0, el seno hiperbólico de 0.

SUMA

Suma todos los números de un área de celdas.

Sintaxis

SUMA(Número1; Número2; ...; Número30)
Número de 1 a 30 son hasta 30 argumentos cuya suma se va a calcular.

Ejemplo

Si ingresa los números2; 3 y 4 en la caja de texto 1; 2 y 3, 9 será devuelto como el resultado.
=SUMA(A1;A3;B5) calcula la suma de las tres celdas. =SUMA (A1:E10) calcula la suma de todas las celdas en el rango de A1 a E10.
Las condiciones unidas mediante Y se pueden utilizar junto con la función SUMA() de esta forma:
Ejemplo hipotético: Ha introducido facturas en una tabla. La columna A contiene el valor de fecha de la factura, en la columna B los importes. Quiere encontrar una fórmula que puede utilizar para devolver el total de todas las sumas sólo para un determinado mes, por ejemplo, sólo la cantidad para el período >= 2008-01-01 a <2008-02-01. El rango de valores a la fecha abarca A1:A40, el rango que contiene los importes que se totalizaron es B1:B40. C1 contiene la fecha de inicio, 2008-01-01, de las facturas que se han de incluir y C2 la fecha, 2008 -02-01, que ya no está incluido.
Escriba la fórmula siguiente como fórmula de matriz:
=SUMA((A1:A40>=C1)*(A1:A40<C2)*B1:B40)
Para escribirla como fórmula de matriz, debe pulsar las teclas Mayús + Control + Intro para cerrar la fórmula, en lugar de pulsar solamente Intro. La fórmula aparece entre llaves en la barra de fórmulas.
{=SUMA((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}
La formula es basada en el hecho de que el resultado de una comparación es 1 si el criterio es conocido y 0 si el criterio no es conocido. La comparación de resultados individuales será tratada como un arreglo y utilizados en la matriz de multiplicación, y al final los valores individuales se sumaron para dar el resultado matriz.

SUMAR.SI

Agrega las celdas especificadas por un criterio determinado. Esta función se usa para buscar en un área un determinado valor.
La búsqueda admite expresiones regulares. Puede escribir "todo.*", por ejemplo, para buscar la primera aparición de "todo" seguido por cualquier combinación de caracteres. Si desea buscar un texto que sea a su vez una expresión regular, cada carácter debe ir precedido con el carácter \ (barra invertida). Puede activar y desactivar la evaluación automática de expresiones regulares en Herramientas - Opciones - LibreOffice Calc - Calcular.

Sintaxis

SUMAR.SI(Rango; Criterio; Suma de Rango)
Rango es el área en la que se aplicarán los criterios.
Criterios es la celda en que se muestra el criterio de búsqueda, o es el criterio de búsqueda en sí. Si un criterio se escribe en la fórmula, debe quedar limitado por comillas dobles.
Rango de suma es el área desde el que se suman los valores. Si este parámetro no se ha indicado, se suman los valores encontrados en el rango.

SUMAR.SI soporta el operador de concatenación (~) solamente en el parámetro de Criterio, y si el         Rango de suma no esta definido.

Ejemplo

Para sumar únicamente números negativos: =SUMAR.SI(A1:A10;"<0")
=SUMAR.SI(A1:A10;">0";B1:10) suma los valores del área B1:B10 sólo si los valores correspondientes en el área A1:A10 son >0.
Consulte CONTAR.SI() para obtener más ejemplos de sintaxis que puedan utilizarse con SUMAR.SI().

TAN

Devuelve la tangente del ángulo especificado.

Sintaxis

TAN(Número)
Devuelve la tangente (trigonemétrica) del Número, el ángulo en radianes
To return the tangent of an angle in degrees, use the RADIANS function.

Ejemplo

=TAN(PI()/4) devuelve 1, la tangente de PI/4 radianes.
=TAN(RADIANES(45)) devuelve 1, la tangente de 45 grados.

TANH

Devuelve la tangente hiperbólica de un número.

Sintaxis

TANH(Número)
Devuelve la tangente hiperbólica del Número.

Ejemplo

=TANH(0) devuelve 0, la tangente hiperbólica de 0.

SUBTOTAL

Calcula subtotales. Si un área ya contiene subtotales, éstos no se utilizan en otros cálculos. Utilice esta función en combinación con los filtros automáticos para tener en cuenta únicamente los registros filtrados.

Sintaxis

SUBTOTAL(Función; Rango)
Función es un número que representa una de las siguientes funciones:

Índice de funciones	Función
1	PROMEDIO
2	CONTAR
3	CONTARA
4	MÁX
5	MÍN
6	PRODUCTO
7	DESVPROM
8	DESVESTP
9	SUMA
10	VAR
11	VARP

Área es el área cuyas celdas están incluidas.

Ejemplo

El área de celdas A1:B5 contiene una tabla con ciudades en la columna A y cifras relacionadas en la columna B. Ha utilizado un Filtro automático para ver únicamente las filas que contienen la ciudad de Hamburgo. Desea ver la suma de las cifras mostradas; es decir, el subtotal de las filas filtradas. En tal caso, la fórmula correcta será:
=SUBTOTAL(9;B2:B5)

EUROCONVERT

Convierte entre las monedas nacionales europeas antiguas y los euros.

Sintaxis

EUROCONVERT(Valor; "De_moneda"; "A_moneda", precisión_completa, precisión_triangulación)
Valor es la cantidad de moneda que se va a convertir.
De_moneda y A_moneda son las unidades monetarias que se convertirán respectivamente. Deben ser texto, la abreviatura oficial de la moneda (por ejemplo, "EUR"). La Comisión Europea estableció los tipos de cambio (mostrados por Euro).
Precisión_completa es opcional. Si se omite o es Falso, el resultado se redondea según los decimales de la moneda de destino. Si Precisión_completa es Verdadero, el resultado no se redondea.
Precisión_triangulación es opcional. Si se proporciona Precisión_triangulación y >=3, el resultado intermedio de una conversión triangular (moneda1,EUR,moneda2) se redondea a dicha precisión. Si se omite Precisión_triangulación, el resultado intermedio no se redondea. Además si A moneda es "EUR", Precisión_triangulación se utiliza como si se necesitase la triangulación y se aplicase la conversión de EUR a EUR.

Ejemplos

=EUROCONVERT(100;"ATS";"EUR") convierte 100 chelines austríacos a euros.
=EUROCONVERT(100;"EUR";"DEM") convierte 100 euros a marcos alemanes.

REDONDEA.IMPAR

Redondea un número positivo hacia arriba hasta el entero impar más próximo siguiente y un número negativo hacia abajo hasta el entero impar más próximo.

Sintaxis

REDONDEA.IMPAR(Número)
Devuelve el Número redondeado para el próximo entero impar, lejos del cero.

Ejemplo

=REDONDEA.IMPAR(1.2) devuelve 3.
=REDONDEA.IMPAR(1) devuelve 1.
=REDONDEA.IMPAR(0) devuelve 1.
=REDONDEA.IMPAR(-3.1) devuelve -5.

ABS

Devuelve el valor absoluto de un número.

Sintaxis

ABS(Número)
Número es el valor cuyo valor absoluto debe calcularse. El valor absoluto de un número es su valor sin el signo +/-.

Ejemplo

=ABS(-56) devuelve 56.
=ABS(12) devuelve 12.
=ABS(0) devuelve 0.

Funciones de Estadisticas - Financiera

  Funciones de Estadisticas

COEFICIENTE.R2

Calcula el cuadrado del coeficiente de correlación de Pearson según los valores especificados. El coeficiente R2, también conocido como coeficiente de determinación, es una medida para obtener un buen ajuste, que se puede utilizar para producir un análisis de regresión.

Sintaxis

COEFICIENTE.R2(DatosY; DatosX)
DatosY es una matriz o área de puntos de datos.
DatosX es una matriz o rango de puntos de datos.

Ejemplo

=COEFICIENTE.R2(A1:A20;B1:B20) calcula el coeficiente de determinación para los conjuntos de datos en las columnas A y B.

NTERSECCIÓN.EJE

Calcula el punto de intersección de una línea con los valores y utilizando los valores x e y conocidos.

Sintaxis

INTERSECCIÓN.EJE(DatosY; DatosX)
DatosY es el conjunto dependiente de observaciones o datos.
DatosX es el conjunto independiente de observaciones o datos.
Se deben utilizar nombres, matrices o referencias que contengan números. También se pueden escribir números directamente.

Ejemplo

Para calcular el eje de intersección se utilizan como valor Y las celdas D3:D9 y como valor X, las celdas C3:C9 de la hoja de ejemplo. La entrada queda como sigue:
=INTERSECCIÓN.EJE(D3:D9;C3:C9) = 2,15.

DISTR.EXP

Devuelve la distribución exponencial.

Sintaxis

DISTR.EXP(Número; Lambda; C)
Número es el valor de la función.
Lambda es el valor del parámetro.
C es un valor lógico que determina la forma de la función. C = 0 calcula la función de densidad y C = 1 calcula la distribución.

Ejemplo

=DISTR.EXP(3;0.5;1) devuelve 0,78.

CONTARA

Cuenta los valores que hay en la lista de argumentos. Las entradas de texto también se cuentan, incluso si contienen una cadena vacía de longitud 0. Si un argumento es una matriz o referencia, se hace caso omiso de las celdas vacías que pudieran contener.

Sintaxis

CONTAR(Valor1; Valor2; ... Valor30)
Valor 1; Valor 2, ... son argumentos del 1 al 30 que representan los valores que se van a contar.

Ejemplo

Las entradas 2, 4, 6 y ocho en el valor de los campos 1-4 han de ser contados.
=CONTARA(2;4;6;"ocho") = 4. La cantidad de valores es por tanto 4.

CONTAR

Cuenta los números que hay en la lista de argumentos. No se toman en consideración las entradas de texto.

Sintaxis

CONTAR(Valor1; Valor2; ... Valor30)
Valor 1; Valor 2... son valores o áreas del 1 al 30 que representan los valores que se van a contar.

Ejemplo

Las entradas 2, 4, 6 y 8 en el valor de los campos 1-4 han de ser contados.
=CONTAR(2;4;6;"ocho") = 3. La cantidad de números es por tanto 3.

PRUEBA.JI

Devuelve la probabilidad de una desviación de una distribución aleatoria de dos series de prueba basándose en las pruebas del cuadrado de ji para la independencia. PRUEBA.JI devuelve la distribución del cuadrado de ji de los datos.
El intervalo de probabilidad calculado mediante PRUEBA.JI también se puede determinar mediante DISTR.JI; en este caso en lugar de una serie de datos, el cuadrado de ji de la muestra se debe presentar como parámetro.

Sintaxis

PRUEBA.CHI(DatoB; DatoE)
DatosB es la matriz de las observaciones.
DatosE es el intervalo de valores esperados.

Ejemplo

A (observado)	B (previsto)
1	195	170
2	151	170
3	148	170
4	189	170
5	183	170
6	154	170

=PRUEBA.CHI(A1:A6;B1:B6) es igual a 0,02. Es la probabilidad con la que se cumple la distribución teórica del cuadrado de chi.

INV.CUAD.CHI

Devuelve el valor inverso de DISTR.CUAD.CHI.

Sintaxis

Probabilidad es el valor del intervalo de probabilidad para el cual se debe calcular la distribución de cuadrado de chi inversa.
Grados de libertad son los grados de libertad para la función cuadrado de chi.

DISTR.CUAD.CHI

Devuelve el valor de la función de densidad de probabilidad o la función de distribución acumulativa para la distribución del cuadrado de chi.

Sintaxis

DISTR.CUAD.CHI(Número; Grados de libertad; Acumulativa)
Número es el número para el que debe calcularse la función.
Grados de libertad son los grados de libertad para la función cuadrado de chi.
Acumulativa (opcional): 0 o Falso calcula la función de densidad de probabilidad. Otros valores o Verdadero u omitido calcula la función de distribución acumulativa.

PRUEBA.JI.INV

Devuelve el inverso de la probabilidad de una cola de la distribución del cuadrado de ji.

Sintaxis

PRUEBA.CHI.INV(Número; GradosdeLibertad)
Número es el valor de la probabilidad de error.
GradosdeLibertad son los grados de libertad del experimento.

Ejemplo

Se tira un dado 1020 veces. Los números de las caras del 1 al 6 aparecen 195, 151, 148, 189, 183 y 154 veces (valores observados). Se debe verificar la hipótesis de si el dado es real.
La distribución del cuadrado de ji de la muestra se calcula con la fórmula anterior. Como el valor previsto para cada uno de los números de las caras en n dados n veces es 1/6, entonces 1020/6 = 170, la fórmula da un valor de cuadrado de ji de 13,27.
Si el cuadrado de ji (observado) es mayor o igual al cuadrado PRUEBA.JI.INV (teórico), entonces se descarta la hipótesis, pues la desviación entre teoría y práctica es demasiado grande. Si el cuadrado ji observado es inferior a PRUEBA.JI.INV, entonces la hipótesis cumple el intervalo de probabilidad de error dado.
=PRUEBA.CHI.INV(0.05;5) devuelve 11,07.
=PRUEBA.CHI.INV(0.02;5) devuelve 13,39.
Con un intervalo de probabilidad de error del 5% el dado no es de verdad; si el intervalo de error es del 2% no hay razón para cuestionar su veracidad.

DISTR.JI

Calcula el valor de probabilidad para el cuadrado de ji indicado para la confirmación de una hipótesis. DISTR.JI compara el valor del cuadrado de ji de una muestra aleatoria, que se calcula a partir de la suma de (valor observado-valor previsto)^2/valor previsto en todos los valores con la distribución teórica del cuadrado de ji; origina el intervalo de probabilidad de error de la hipótesis que se debe demostrar.
El intervalo de probabilidad calculado mediante DISTR.JI también se puede determinar mediante PRUEBA.JI; en este caso, en lugar del cuadrado de ji de la muestra, los datos observados y previstos se deben suministrar como parámetros.

Sintaxis

DISTR.CHI(Número; GradosdeLibertad)
Número es el valor de cuadrado de chi de la muestra aleatoria utilizada para determinar la probabilidad de error.
GradosdeLibertad son los grados de libertad del experimento.

Ejemplo

=DISTR.CHI(13,27; 5) es igual a 0,02.
Si el valor del cuadrado de ji de la muestra asciende a 13,27 y el experimento tiene 5 grados libertad, entonces la hipótesis se cumple con un intervalo de probabilidad de error del 2%.

DISTR.BINOM

Devuelve la probabilidad de distribución binomial de un término individual.

Sintaxis

DISTR.BINOM(X; Ensayos; SP; C)
X es el número de éxitos en un conjunto de pruebas.
Ensayos es el número de intentos independientes.
prob_éxito es la probabilidad de éxito de cada intento.
C = 0 calcula la probabilidad de un único evento y C = 1 calcula la probabilidad acumulativa.

Ejemplo

=DISTR.BINOM(A1;12;0.5;0) muestra (si se especifican los valores 0 a 12 en A1) la probabilidad que resulta de tirar 12 veces una moneda y que salga Cara exactamente el número de veces especificado en A1.
=DISTR.BINOM(A1;12;0.5;1) muestra las probabilidades acumuladas para la misma serie. Por ejemplo, si A1 = 4, la probabilidad acumulada de la serie es 0, 1, 2, 3 o 4 veces encabezado (lógica OR no exclusiva).

DISTR.BETA.INV

Devuelve el inverso de la función de densidad de probabilidad beta acumulada.

Sintaxis

DISTR.BETA.INV(Número; Alpha; Beta; Inicio; Fin)
Número es el valor entre Inicio y Fin en el que evaluar la función.
Alfa es un parámetro para la distribución.
Beta es un parámetro para la distribución.
Inicio (opcional) es el límite inferior de Número.
Fin (opcional) es el límite superior de Número.
En las funciones de LibreOffice Calc, los parámetros marcados como "opcionales" se pueden omitir únicamente si no les sigue ningún parámetro. Por ejemplo, en una función que tiene cuatro parámetros cuyos dos últimos están marcados como "opcionales", se puede omitir el parámetro 4 o los parámetros 3 y 4; sin embargo, no se puede omitir solamente el parámetro 3.

Ejemplo

=DISTR.BETA.INV(0,5;5;10) devuelve el valor 0,33.

DISTR.BETA

Devuelve la función beta.

Sintaxis

DISTR.BETA(Número; Alfa; Beta; Inicio; Fin;Acumulativa)
Número es el valor entre Inicio y Fin en el que evaluar la función.
Alfa es un parámetro para la distribución.
Beta es un parámetro para la distribución.
Inicio (opcional) es el límite inferior de Número.
Fin (opcional) es el límite superior de Número.
Acumulativa (opcional) puede ser 0 o Falso para calcular la función de densidad de probabilidad. Puede ser cualquier otro valor o Verdadero u omitirse para calcular la función de distribución acumulativa.
En las funciones de LibreOffice Calc, los parámetros marcados como "opcionales" se pueden omitir únicamente si no les sigue ningún parámetro. Por ejemplo, en una función que tiene cuatro parámetros cuyos dos últimos están marcados como "opcionales", se puede omitir el parámetro 4 o los parámetros 3 y 4; sin embargo, no se puede omitir solamente el parámetro 3.

Ejemplo

=DISTR.BETA(0,75;3;4) devuelve el valor 0,96.

B

Devuelve la probabilidad de una muestra con distribución binomial.

Sintaxis

B(Ensayos; SP; T1; T2)
Ensayos es el número de intentos independientes.
prob_éxito es la probabilidad de éxito de cada intento.
T1 define el límite inferior para el número de intentos.
T2 (opcional) define el límite superior para el número de intentos.

Ejemplo

¿Cuál debe ser la probabilidad si al tirar un dado 10 veces sale dos veces el seis? La probabilidad para un seis (o para cualquier otro número) es 1/6, luego el resultado es la siguiente fórmula:
=B(10;1/6;2) devuelve una probabilidad del 29%.

Funciones de Finanzas

SYD

Calcula la tasa de depreciación de aritmética decreciente.
Utilice esta función para calcular el importe de amortización de un período determinado durante el período de amortización completo de un objeto. La amortización digital reduce el importe de amortización de un período a otro en un importe fijo.

Sintaxis

SYD(Costo; Valor de salvamento; Vida; Periodo)
Costo es el costo inicial de un activo.
Salvamento es el valor de un activo tras la amortización.
Vida es el periodo que fija el intervalo de tiempo durante el cual un activo se amortiza.
Período define el período para el que debe calcularse la amortización.

Ejemplo

Un equipo de vídeo con un precio de compra de 50.000 unidades monetarias debe depreciarse anualmente durante 5 años. El valor de salvamento debe ser de 10.000 unidades monetarias. Determine la amortización correspondiente al primer año.
=SYD(50000;10000;5;1)=13.333,33 unidades monetarias. El monto de la amortización para el primer año es de 13.333,33 unidades monetarias.
Es recomendable definir una tabla de amortización para ver fácilmente todas las tasas de amortización por período. Si introduce una tras otra las diferentes fórmulas de cálculo de amortización de LibreOffice Calc, se muestra también la forma de amortización más ventajosa en cada caso. Cree una tabla del modo siguiente:

A	B	C	D	E
1	Costo inicial	Valor de salvamento	Vida útil	Intervalo de tiempo	Amortiz. SYD
2	50.000 unidades monetarias	10.000 unidades monetarias	5	1	13.333,33 unidades monetarias
3	2	10.666,67 unidades monetarias
4	3	8.000,00 unidades monetarias
5	4	5.333,33 unidades monetarias
6	5	2.666,67 unidades monetarias
7	6	0,00 unidades monetarias
8	7
9	8
10	9
11	10
12
13	0	Total	40.000,00 unidades monetarias

La fórmula de E2 es la siguiente:
=SYD($A$2;$B$2;$C$2;D2)
Esta fórmula se duplica en la columna E hasta la celda E10 (seleccionar E2 y arrastrar la esquina inferior derecha hacia abajo con el ratón).
En la celda E13 se encuentra la fórmula que suma todos los importes de la amortización para su comprobación. Se sirve de la función SUMAR.SI porque los valores negativos en E8:E11 no deben tenerse en cuenta. La condición >0 se encuentra en la celda A13. La fórmula de E13 es la siguiente:
=SUMAR.SI(E2:E11;A13)
A continuación podrá ver la amortización a 10 años, consultarla con un valor de salvamento de 1 unidad monetaria, introducir otros precios de compra, etc.

CANTIDAD.RECIBIDA

Calcula la cantidad recibida que se paga por un valor a interés fijo en un momento determinado.

Sintaxis

CANTIDAD.RECIBIDA("Liquidación"; "Vencimiento"; Inversión; Descuenta; Bases)
Liquidación es la fecha de compra de la garantía.
Vencimiento es la fecha cuando la garantía vence (expira).
Inversión es el valor de la compra.
Descuento es el porcentaje de descuento en la adquisición de la garantía.
Base es elegido de entre una lista de opciones y se indica como el año se habrá de calcular.

Base	Cálculo
0 ó ninguno	Método de EE.UU. (NASD), 12 meses a 30 días cada mes
1	cantidad exacta de días del mes, cantidad exacta de días del año
2	cantidad exacta de días del mes, para un año se toman 360 días.
3	cantidad exacta de días del mes, para un año se toman 365 días
4	Método de Europa, 12 meses a 30 días

Ejemplo

Fecha de liquidación: 15 de febrero de 1999, fecha de vencimiento: 15 de mayo de 1999, cantidad de inversión: 1000 unidades monetarias, Tasa de descuento: 5,75 por ciento, Bases: Balance_diario/360 = 2.
La cantidad de liquidación en la fecha de vencimiento se calcula de esta forma:
=CANTIDAD.RECIBIDA ("1999-02-15";"1999-05-15";1000;0.0575;2) devuelve 1.014,420266.

VA

Calcula el valor efectivo resultante de una inversión fruto de una serie de pagos regulares.
Utilice esta función para calcular la suma de dinero que debe invertir hoy a un interés fijo para recibir pagos regulares (anualidades) durante un determinado número de períodos. Opcionalmente, también es posible definir el importe que debe quedar disponible al final de estos períodos. Se puede especificar también si el importe que debe satisfacerse se abona respectivamente al inicio o al final de un período.
Indique los valores en forma de números, expresiones o referencias. Si, por ejemplo, percibe intereses anuales del 8% pero desea definir como período el mes, introduzca 8%/12 en el campo Tasa y LibreOffice Calc calcula automáticamente el factor correcto.

Sintaxis

VA(tASA; NPer; Cuota Fija; Valor Futuro; Tipo)
Tasa es la tasa de interés por período.
NPer es la cantidad total de periodos de pagos (periodo de pago).
Pago es el pago regular realizado en cada periodo.
VF (opcional) define el valor futuro que queda tras el pago de la última cuota.
Tipo (opcional) es la fecha de vencimiento para los pagos. Tipo = 1 significa que el vencimiento tiene lugar al inicio del período, mientras que Tipo = 0 (el valor predeterminado) indica que el vencimiento se produce al final del período.
En las funciones de LibreOffice Calc, los parámetros marcados como "opcionales" se pueden omitir únicamente si no les sigue ningún parámetro. Por ejemplo, en una función que tiene cuatro parámetros cuyos dos últimos están marcados como "opcionales", se puede omitir el parámetro 4 o los parámetros 3 y 4; sin embargo, no se puede omitir solamente el parámetro 3.

Ejemplo

¿Cuál es el valor efectivo de una inversión si se abonan 500 unidades monetarias al mes y el tipo de interés anual es del 8%? Siendo el período de pago de 48 meses y el valor final 20.000 unidades monetarias:
=VA(8%/12;48;500;20000) = -35.019,37 unidades monetarias. En las condiciones especificadas, se tienen que depositar 35,019.37 unidades monetarias el día de hoy, si se desea recibir 500 unidades monetarias mensualmente por 48 meses, quedando 20.000 unidades pendientes al final. La verificación cruzada indica que 48 x 500 unidades monetarias + 20.000 unidades monetarias = 44.000 unidades monetarias. La diferencia entre este monto y las 35.000 unidades depositadas representa el interés pagado.
Si en lugar de introducir valores directamente lo hace en forma de referencia en la fórmula, puede efectuar cálculos estimativos del tipo "Qué pasaría si..." Recuerde definir las referencias a las constantes como referencias absolutas. En las funciones de amortización se encuentran ejemplos de este tipo de aplicación.

INT.PAGO.DIR

Calcula el nivel de interés en el caso de cuotas de amortización invariables.

Sintaxis

INT.PAGO.DIR(Tasa; Periodo; TotalPeriodos; Inversión)
Tasa establece la tasa periódica de interés.
Período es el número de cuotas para el cálculo de intereses.
PeríodosTotales es la cantidad total de periodos de liquidación.
Inversión es la cantidad invertida.

Ejemplo

Para un crédito de 120.000 unidades monetarias, un período de dos años y cuotas mensuales con una tasa de interés anual del 12%, se necesita conocer el nivel de interés al cabo de 1,5 años.
=INT.PAGO.DIR(1%;18;24;120000) = -300 unidades monetarias. El interés mensual después de 1,5 años, alcanza las 300 unidades monetarias.

TIR

Calcula la tasa interna de retorno de una inversión. Los valores representan el efectivo a intervalos regulares: al menos un valor debe ser negativo (pagos) y al menos un valor debe ser positivo (ingreso).

Sintaxis

TIR(Valores; Valor de Referencia)
Valores representa a una matriz que contiene los valores.
Estimación (opcional) es el valor estimado. Se usa un método iterativo para calcular la tasa interna de retorno. Si solamente se pueden proporcionar algunos valores, se deben proporcionar valores estimados iniciales para permitir la iteración.

Ejemplo

Bajo el supuesto de que los contenidos de las celdas sean: A1=-10000, A2=3500, A3=7600 y A4=1000, la formula =TIR(A1:A4) da un resultado de 11,33%.

INT.EFECTIVO

Calcula el interés efectivo anual respecto a una tasa de interés nominal.
Como la tasa de interés nominal se basa en un vencimiento de intereses al final del período de cálculo y en cambio, por lo general, los intereses se abonan mensual o trimestralmente, incluso en otros períodos anteriores al final del período de cálculo (es decir, se pagan por adelantado), los intereses efectivos se incrementan con el número de pagos parciales de intereses.

Sintaxis

EFFECTIVE(Nom; P)
Nom es el interés nominal.
P es la cantidad de periodos de pago de intereses por año.

Ejemplo

Si los intereses nominales anuales son del 9,75 % y se han previsto cuatro períodos de cálculo de intereses, ¿cuál es la tasa de interés real (intereses efectivos)?
=INT.EFECTIVO(9.75%;4) = 10,11% La tasa anual de interés efectivo es por lo tanto de 10,11%.

INT.EFECTIVO_ADD

Calcula la tasa efectiva de interés anual a partir de la tasa de interés nominal y el número de pagos de intereses por año.

Las funciones cuyo nombre termina con _ADD devuelven el mismo resultado que las funciones correspondientes de Microsoft Excel. Utilice las funciones sin _ADD para obtener resultados basados en estándares internacionales. Por ejemplo, la función SEM.DEL.AÑO calcula el número de semana de una fecha concreta basándose en el estándar internacional ISO 6801, mientras que SEM.DEL.AÑO_ADD devuelve el mismo número de semana que Microsoft Excel.

Sintaxis

EFFECT_ADD(NominalRate; NPerY)
TasaNominal es la tasa nominal anual de interés.
NPerY es el número de pagos de intereses por año.

Ejemplo

¿Cuál es el interés efectivo con un interés nominal del 5,25% y un pago trimestral?
=INT.EFECTIVO_ADD(0,0525;4) devuelve 0,053543 % o 5,3543 %.

DURACION_ADD

Calcula la duración, en años, de un valor de interés fijo.

Las funciones cuyo nombre termina con _ADD devuelven el mismo resultado que las funciones correspondientes de Microsoft Excel. Utilice las funciones sin _ADD para obtener resultados basados en estándares internacionales. Por ejemplo, la función SEM.DEL.AÑO calcula el número de semana de una fecha concreta basándose en el estándar internacional ISO 6801, mientras que SEM.DEL.AÑO_ADD devuelve el mismo número de semana que Microsoft Excel.

Sintaxis

DURATION_ADD("Liquidación"; "Vencimiento"; Cupón; Rendimiento; Frecuencia; Bases)
Liquidación es la fecha de compra de la garantía.
Vencimiento es la fecha cuando la garantía vence (expira).
Vale es la tasa anual de interés del vale (tasa nominal de interés)
Rendimeinto es la ganancia anual de la garantía.
Frecuencia es la cantidad de pagos de intereses por año (1, 2 o 4).
Base es elegido de entre una lista de opciones y se indica como el año se habrá de calcular.

Base	Cálculo
0 ó ninguno	Método de EE.UU. (NASD), 12 meses a 30 días cada mes
1	cantidad exacta de días del mes, cantidad exacta de días del año
2	cantidad exacta de días del mes, para un año se toman 360 días.
3	cantidad exacta de días del mes, para un año se toman 365 días
4	Método de Europa, 12 meses a 30 días

Ejemplo

Un valor se compra el 01-01-2001; la fecha de vencimiento es el 01-01-2006. El interés nominal asciende al 8 %. La rentabilidad es del 9 %. El interés se paga semestralmente (la frecuencia es 2). ¿Cuál es la duración al realizar un cálculo (base 3) diario?
=DURACION_ADD("2001-01-01";"2006-01-01";0.08;0.09;2;3)

TASA.DESC

Calcula la provisión (descuento) de un valor en forma de porcentaje.

Sintaxis

DISC("Liquidación"; "Vencimiento"; Precio; Redención; Bases)
Liquidación es la fecha de compra de la garantía.
Vencimiento es la fecha cuando la garantía vence (expira).
Precio es el precio de la garantía por cada 100 unidades monetarias de valor nominal.
Rescate es el valor de rescate de la garantía por cada 100 unidades monetarias de valor nominal.
Base es elegido de entre una lista de opciones y se indica como el año se habrá de calcular.

Base	Cálculo
0 ó ninguno	Método de EE.UU. (NASD), 12 meses a 30 días cada mes
1	cantidad exacta de días del mes, cantidad exacta de días del año
2	cantidad exacta de días del mes, para un año se toman 360 días.
3	cantidad exacta de días del mes, para un año se toman 365 días
4	Método de Europa, 12 meses a 30 días

Ejemplo

Se compra un valor el 25-01-2001; la fecha de vencimiento es el 15-11-2001. El precio (precio de compra) es 97, el valor de rendimiento es 100. Con el cálculo diario (base 3) ¿cuál es la liquidación (descuento)?
=TASA.DESC("2001-01-25";"2001-11-15";97;100;3) devuelve alrededor de 0,0372 % 3,72 %.

DDB

Devuelve la depreciación de un activo en un período específico según el método aritmético degresivo.
Esta forma de depreciación es la adecuada si precisa un valor más alto de depreciación inicial, a diferencia de la depreciación lineal. El valor de depreciación disminuye con cada período; suele utilizarse en aquellos activos que pierden más valor poco después de su adquisición (por ejemplo, automóviles o equipos informáticos). Tenga en cuenta que el valor contable nunca llegará a cero con este tipo de cálculo.

Sintaxis

DDB(Costo; Valor de salvamento; Vida; Periodo; Factor)
Costo fija el costo inicial de un activo.
Salvamento fija el valor de un activo al final de su vida.
Vida es el número de períodos (por ejemplo, años o meses) que definen la duración del uso del activo.
Período define el período para el que debe calcularse el valor.
Factor (opcional) es el factor por el que disminuye la amortización. Si no se indica un valor, el factor predeterminado es 2.

Ejemplo

Un equipo informático con un precio de compra de 75.000 unidades monetarias debe amortizarse mensualmente durante 5 años. El valor residual debe ser 1 unidad monetaria. El factor es 2.
=DDB(75000;1;60;12;2) = 1.721,81 unidades monetarias. Por lo tanto, la amortización degresiva en plazos dobles en el mes doce tras la compra es de 1.721,81 unidades monetarias.

DB

Devuelve la depreciación de un activo en un período específico según el método de amortización por doble disminución de saldo.
Utilice este modo de amortización para obtener, al contrario que con el modo lineal, un valor de amortización mayor al inicio de la amortización. Con cada período de amortización, dicho valor se reduce en las amortizaciones ya deducidas del valor de compra.

Sintaxis

DB(Costo; Valor de salvamento; Vida; Periodo; Mes)
Costo es el costo inicial de un activo.
Salvamento es el valor de un activo al final de la amortización.
Vida define el período durante el cual se amortiza un activo.
Período es la duración de cada período. La duración debe indicarse en la misma unidad de tiempo que el periodo de amortización.
Mes (opcional) indica la cantidad de meses para el primer año de amortización. Si no se indica nada, se usa el valor 12 como predeterminado.

Ejemplo

Un equipo informático con un coste de compra inicial de 25.000 unidades monetarias debe amortizarse en un período de tres años. El Valor de salvamento al final de la amortización debe ser de 1.000 unidades monetarias. La duración de un período es de 30 días.
=DB(25000;1000;36;1;6) = 1.075,00 unidades monetarias
La amortización geométrica decreciente del equipo informático es de 1.075,00 unidades monetarias.

AMORTIZ.LIN

Calcula el importe de la depreciación en un período de liquidación en forma de amortización lineal. Si el activo fijo se adquiere durante el período de liquidación, se tiene en cuenta el importe proporcional de la depreciación.

Sintaxis

AMORTIZ.LIN(Costos; Fecha de compra; Primer periodo; Valor de salvamento; Periodo; Tasa; Base)
Costo significa el costo de adquisición.
FechaDeCompra es la fecha de la adquisición.
PrimerPeriodo es la fecha de vencimiento del primer periodo de liquidación.
Salvamento es el valor de salvamento del activo de capital al final de su vida de amortización.
Periodo es el periodo de liquidación a considerar.
Tasa es la tasa de amortización.
Base es elegido de entre una lista de opciones y se indica como el año se habrá de calcular.

Base	Cálculo
0 ó ninguno	Método de EE.UU. (NASD), 12 meses a 30 días cada mes
1	cantidad exacta de días del mes, cantidad exacta de días del año
2	cantidad exacta de días del mes, para un año se toman 360 días.
3	cantidad exacta de días del mes, para un año se toman 365 días
4	Método de Europa, 12 meses a 30 días

AMORTIZ.PROGRE

Calcula el importe de la depreciación en un período de liquidación en forma de amortización degresiva. A diferencia de AMORTIZ.LIN, en esta función se utiliza un coeficiente de depreciación independiente de la vida útil depreciable.

Sintaxis

AMORTIZ.PROGRE(Costo; Fecha de compra; Primer período; Valor de salvamento; Período; Tasa; Base)
Costo son los costos de adquisición.
FechaDeCompra es la fecha de la adquisición.
PrimerPeriodo es la fecha de vencimiento del primer periodo de liquidación.
Salvamento es el valor de salvamento del activo de capital al final de la vida de amortización.
Periodo es el periodo de liquidación a considerar.
Tasa es la tasa de amortización.
Base es elegido de entre una lista de opciones y se indica como el año se habrá de calcular.

Base	Cálculo
0 ó ninguno	Método de EE.UU. (NASD), 12 meses a 30 días cada mes
1	cantidad exacta de días del mes, cantidad exacta de días del año
2	cantidad exacta de días del mes, para un año se toman 360 días.
3	cantidad exacta de días del mes, para un año se toman 365 días
4	Método de Europa, 12 meses a 30 días

INT.ACUM.V

Calcula el interés acumulado de un valor en el caso de un pago único en la fecha de liquidación.

Sintaxis

INT.ACUM.V(Emisión; Liquidación; Tasa; Valor Nominal; Bases)
Emisión es la fecha de emisión de la garantía.
Liquidación es la fecha en que se deben calcular los intereses devengados hasta ese momento.
Tasa es la tasa nominal anual de interés (tasa de interés del vale).
Nominal es el valor nominal de la garantía.
Base es elegido de entre una lista de opciones y se indica como el año se habrá de calcular.

Base	Cálculo
0 ó ninguno	Método de EE.UU. (NASD), 12 meses a 30 días cada mes
1	cantidad exacta de días del mes, cantidad exacta de días del año
2	cantidad exacta de días del mes, para un año se toman 360 días.
3	cantidad exacta de días del mes, para un año se toman 365 días
4	Método de Europa, 12 meses a 30 días

Ejemplo

Se emite un título el 01-04-2001. La fecha de vencimiento se establece para el 15-06-2001. El interés es del 0,1 % o 10 % y el valor nominal es de 1.000 unidades monetarias. La base del cálculo diario /anual es el cálculo diario (3). ¿Qué interés se ha acumulado?
=INT.ACUM.V("2001-04-01";"2001-06-15";0.1;1000;3) devuelve 20,54795.

INT.ACUM

Calcula el interés acumulado de un valor en el caso de pagos periódicos de intereses.

Sintaxis

ACCRINT(Emisión; PrimerInterest; Liquidación; Tasa; ValorPar; Frecuencia; Bases)
Emisión es la fecha de emisión de la garantía.
PrimerInterés es la fecha del primer interés de la garantía.
Liquidación es la fecha en que se deben calcular los intereses devengados hasta ese momento
Tasa es la tasa nominal anual de interés (tasa de interés del vale)
Nominal es el valor nominal de la garantía.
Frecuencia es la cantidad de pagos de interés al año (1, 2 o 4).
Base es elegido de entre una lista de opciones y se indica como el año se habrá de calcular.

Base	Cálculo
0 ó ninguno	Método de EE.UU. (NASD), 12 meses a 30 días cada mes
1	cantidad exacta de días del mes, cantidad exacta de días del año
2	cantidad exacta de días del mes, para un año se toman 360 días.
3	cantidad exacta de días del mes, para un año se toman 365 días
4	Método de Europa, 12 meses a 30 días

Ejemplo

Se emite un título el 28-02-2001. El primer interés se establece para el 31-08-2001. La fecha de liquidación es el 01-05-2001. El interés es del 0,1 % o del 10 %, y el valor nominal es de 1.000 unidades monetarias. El interés se paga semestralmente (la frecuencia es 2). La base es el método estadounidense (0). ¿Qué interés se ha acumulado?
=INT.ACUM("2001-02-28";"2001-08-31";"2001-05-01";0.1;1000;2;0) devuelve 16,94444.

Funciones de Busqueda

BUSCARV es una potente función que nos ayudará en un sinfín de situaciones. Veamos una de ellas: Localizar los datos de un cliente por su número de teléfono.

Ésta función localizará en una lista ordenada un determinado valor, y si lo encuentra nos devuelve el valor almacenado en la celda correspondiente a la columna indicada de la misma fila que el valor buscado.

Los argumentos son:

·         valor_buscado: el valor que vamos a buscar. Habitualmente es una referencia a una celda donde escribimos el valor a buscar.

·         matriz_buscar_en: es el rango de celdas donde buscamos el valor_buscado, incluyendo también todas las columnas de los datos asociados al valor buscado. El valor buscado debe estar en la primera columna del rango que forma la lista. Ésta debe de estar ordenada en orden ascendente por la primera columna; no es obligatorio que sea la columna A de la hoja de cálculo. En el caso de que la lista de valores se pueda ampliar posteriormente, es recomendable asignar a este rango todas las filas disponibles en la hoja de cálculo, como se muestra en la imagen.

·         Índice: es la columna donde se encuentra el valor que queremos consultar. Las columnas se numeran empezando por el número 1. En el ejemplo, el índice 2 que se corresponde con la segunda columna de la lista nos devolverá la razón social del cliente.

·         Ordenado: define el comportamiento de la búsqueda en el caso de no encontrar exactamente el dato buscado. Si indicamos:

·          

o    FALSO(), si la búsqueda no encuentra el valor exacto, nos devolverá en la celda un mensaje de error #N/A, que significa que no ha sido encontrada ninguna coincidencia.

·          

o    VERDADERO(), si la búsqueda no encuentra el valor exacto, nos devolverá el dato correspondiente al valor mayor más próximo.

Veamos un ejemplo. Supongamos una lista con las siguientes columnas: Teléfono, Nombre, Domicilio, Población, Código Postal y Provincia. Ésta lista puede estar almacenada en la misma hoja o en una hoja distinta del documento, e incluso en otro documento.

En nuestro ejemplo, la lista se almacena a partir de la celda A8, si bien no es obligatorio que la primera columna utilizada por la lista sea la A.

En la celda B2 introduciremos el dato a buscar, en nuestro caso el teléfono del cliente.

En la celda B3 introduciremos la fórmula con la función BUSCARV, que para nuestro ejemplo será:

 =BUSCARV(B2;A$8:F$65536;2;FALSO()) 

El rango de celdas donde se buscará el teléfono, incluyendo el resto de datos asociados es A$8:F$65536, pues hemos seleccionado hasta la última fila en previsión de que se añadan nuevos clientes a la lista.

Dado que en la celda B3 queremos que se muestre el nombre del cliente, el índice solicitado es 2, correspondiente a la segunda columna del rango de la lista.

Indicamos el argumento Ordenado como FALSO(), pues en caso de no encontrar una coincidencia exacta preferimos que muestre un mensaje de error en lugar de los datos correspondientes al cliente con el número de teléfono inmediatamente posterior al dato buscado (y no encontrado). 

En las celdas B4, B5 y B6 insertaremos otras fórmulas con la función BUSCARV, en las que todos sus argumentos serán iguales a la introducida en B3, a excepción del argumento índice, que será distinto según la columna que contenga la información que queremos mostrar.

La función BUSCARH tiene un comportamiento paralelo. A diferencia de BUSCARV, que busca un valor en una columna y devuelve los valores situados en la fila, BUSCARH busca el valor en una fila, y devuelve los valores situados en la columna.